Printing Color Separations with WordBasic

Word does not have the inherent capability to print color separations. Instead, you typically must use a full-featured desktop publishing program such as PageMaker to accomplish this task. That being said, you can perform a rudimentary form of color separation by simply changing the text color you don't want to print to white, and then printing the document. Reversing the process will then print the other color.

Note a couple of things about the PrintSeps macro. First, it saves your document. This is done because when the macro is done running, it throws out the document. Saving allows you to load the document from disk at a later time. The other thing to note is that this works only for documents that contain only red and black text. If you have other colors, those colors will print on both passes. If you have white text, it will print with the red pass. If you have graphics, no separation is done on them. (If you have graphics and want them separated, you definitely should be using a desktop publishing program.)

If you are using Word 6 or Word 95, you need to use the following WordBasic version of PrintSeps:

Sub MAIN
FileSave
StartOfDocument

EditFindClearFormatting
EditReplaceClearFormatting

'Change Red to White
EditFindFont .Color = 6
EditReplaceFont .Color = 8

EditReplace .Find = "", \
   .Replace = "", \
   .Direction = 0, \
   .MatchCase = 0, \
   .WholeWord = 0, \
   .PatternMatch = 0, \
   .SoundsLike = 0, \
   .ReplaceAll, \
   .Format = 1, \
   .Wrap = 0, \
   .FindAllWordForms = 0

FilePrintDefault

'Change White back to Red
EditFindFont .Color = 8
EditReplaceFont .Color = 6
EditReplace .ReplaceAll

'Change Auto to White
EditFindFont .Color = 0
EditReplaceFont .Color = 8
EditReplace .ReplaceAll

'Change Black to White
EditFindFont .Color = 1
EditReplaceFont .Color = 8
EditReplace .ReplaceAll

'Change Red to Black
'This is done so that Red will print as Black
'On some printers, non-black colors always
'print as a shade of gray. You want them only
'as black
EditFindFont .Color = 6
EditReplaceFont .Color = 1
EditReplace .ReplaceAll

FilePrintDefault

DocClose 2

End Sub

If you are using WordBasic under Word 6, then there is a slight change that you need to make in the macro. When Microsoft introduced Word 95, they expanded the capabilities of the search and replace function. Thus, some of the parameters for the EditReplace macro command were also enhanced. To make the macro run under Word 6, simply replace the EditReplace block (eleven lines near the beginning of the macro) with the following:

EditReplace .Find = "", \
   .Replace = "", \
   .MatchCase = 0, \
   .ReplaceAll, \
   .Format = 1