Underlining Quoted Text

For some documents, you may have the need to underline information within quotes. For instance, for some legal documents you may need to find all material surrounded by quotes, and then make the information between the quotes underlined. This is different from regular prose writing, where you would use either underlines or quotes, but not both.

If you have a need to search for all quoted text and make it underlined, you can use the following macro. It searches for quotes, and when it finds one, it underlines everything up to the next quote. Note that it will not actually underline the quote marks themselves.

Sub UnderlineQuoted()
    Dim bSearchAgain As Boolean

    Selection.HomeKey Unit:=wdStory
    bSearchAgain = True

    ' start of loop
    While bSearchAgain
        ' set up find of first of quote pair
        With Selection.Find
            .ClearFormatting
            .Text = Chr(34)
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindStop
            .Execute
        End With

        If Selection.Find.Found Then
            Selection.MoveRight Unit:=wdCharacter, Count:=1
            ' switch on selection extend mode
            Selection.Extend
            ' find second quote of this pair
            Selection.Find.Execute
            If Selection.Find.Found Then
                Selection.MoveLeft Unit:=wdCharacter, Count:=1
                ' make it underlined
                Selection.Font.Underline = True
                ' move past end of what was just changed
                Selection.Collapse Direction:=wdCollapseEnd
                Selection.MoveRight Unit:=wdCharacter, Count:=1
            Else
                bSearchAgain = False
            End If
        Else
            bSearchAgain = False
        End If
    Wend
End Sub